BBS灌水机脚本(vb scritp, telnet, bbs, sterm)

'**********************************************************************
'* Filename: water.vbs *
'* Author: Pred yecha@freecity.cn*
'* You may freely modify or redistribute this file *
'**********************************************************************
'
'注意，使用本脚本时，在脚本相同目录下创建一个文件名为Filename的文件，
'脚本把Filename每行内容依次作为文章标题发表在bbs上
'必须先登录到bbs并经如要post的那个板
'
Filename = "water_title.txt"

'Option Explicit
Main
MsgBox ("Script End")

Sub Main()
Const nTimeout = 20
Const ForReading = 1
Dim bConnect, nTime, nScreenHeight, strScreenLine, nDelay

Dim fso, f1, f2, ts, s
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.OpenTextFile(Filename, ForReading)
'b为一个文本文件，脚本把b.txt每行内容依次作为文章标题发表在bbs上

While(Not ts.AtEndOfStream)
  s = ts.ReadLine()
  s = TrimAll(s)
  If s <> "" Then
   If ( Not Expect("离开", 1, 10)) Then
   '判断屏幕第2行是否有"离开"，主要用来判断当前是否在文章列表中
   'Error?
    Exit Sub
   End If

   STermScript.SendConvertedData ("^P") '发表文章
   STermScript.Delay 200 '短暂延时

   If (Not ExpectCursor("标题:", 10)) Then
   '当前光标处是填写标题的地方？
   'Error?
    MsgBox("error?")
    Exit Sub
   End If

   STermScript.SendData (s) '填入标题
   STermScript.SendConvertedData ("^M^M") '送出回车
   STermScript.Delay 200

   STermScript.SendConvertedData ("^W") '结束文章编辑
   STermScript.Delay 200
   If (Not ExpectCursor("(S)转信", 10)) Then
    '出现选择菜单"(S)转信, (F)换行发出，(L)不转信, (A)取消,……"?
    'Error?
    STermScript.SendConvertedData ("^[^[$$") '出现错误，设法回到版面列表状态
   Else
    STermScript.SendConvertedData ("^M") '正常，送出回车
   End If
   STermScript.Delay 20000 '发文时间间隔
  End If
Wend
ts.Close
End Sub

'************************************************************
'* Function: TrimAll(strIn)                                 *
'* Return Value:                                            *
'* 除去字符串中所有可能的空格，tab等                        *
'************************************************************
Function TrimAll(strIn)
Dim s,c, i
s = Trim(strIn)
TrimAll = ""
for i = 1 to Len(s)
  c = Mid(s, i, 1)
  If (Asc(c) = 9) Then
  Else
   TrimAll = TrimAll + c
  End if
Next

End Function

'************************************************************
'* Function: ExpectCursor(ByRef str, ByVal TimeOut)         *
'* Return Value: True 出现   False 未出现                   *
'* 判断在一定时间内，光标所在行是否出现指定字符串           *
'************************************************************
Function ExpectCursor(ByRef str, ByVal TimeOut)
Dim starttime
starttime = Timer
While (Not InStr(STermScript.GetBuffer(STermScript.GetCursorY()), str) > 0)
  STermScript.Delay (200)
  If (Abs(Timer - starttime) > TimeOut) Then
   ExpectCursor = False
   ' MsgBox (str + " not found, timeout")
   Exit Function
  End If
Wend
ExpectCursor = True
End Function

'************************************************************
'* Function: Expect(ByRef str, ByVal l, ByVal TimeOut)      *
'* Return Value: True 出现   False 未出现                   *
'* 判断在一定时间内，指定行是否出现指定字符串               *
'************************************************************
Function Expect(ByRef str, ByVal linenum, ByVal TimeOut)
Dim starttime
starttime = Timer
While (Not InStr(STermScript.GetBuffer(linenum), str) > 0)
  STermScript.Delay (200)
  If (Abs(Timer - starttime) > TimeOut) Then
   Expect = False
   ' MsgBox (str + " not found, timeout")
   Exit Function
  End If
Wend
Expect = True
End Function

BBS灌水机脚本(vb scritp, telnet, bbs, sterm)相关推荐

Casularm 自动灌水机脚本
注:请和 Maxthon 配合使用 [General] Description=guanshui BeginHotkey=119 BeginHotkeyMod=0 Enable=1 [Repeat] ...
VeryCD灌水机演示代码（附另外一个发贴机代码）
VeryCD那个铜光盘才能进候补区的规定很烦人,必须得灌水才能升级,可是又懒得灌,于是写了一个灌水脚本,有人问我要,就干脆发出来共享一下吧. ` 使用方法: 1.把username和passwd改成相 ...
CSDN全自动灌水机
2006年4月 CSDN全自动灌水机老见有人在CSDN上"哦"个不停,怀疑是用的Robot,在WSH中试了下可以用ActiveX,所以写了这么个东西,替我去接分 :D 把 ...
论坛灌水机与注册机问题
话题起头比较大,说明一下,写这篇的起因,论坛最近经常被新用户发布一些不相关的帖子,也没有一定的规律, 而基本都是新注册的用户,还都绑定手机的,起初我们用的是短信验证码,查了一下几天注册的手机号全都是批 ...
论坛灌水机 Delphi代码
本来以为网页里的edit,memo等都和程式里的相同,能够用句柄来控制,但后来才明白,他是不存在句柄的! 查了好久,前几天看到一个关于QQ自动申请的例子.主要就是控制网页各种操作的!总结了一下,做出一 ...
一路问情热门论坛自动灌水机 v2007 免费
Welcome to my blog! <script language="javascript" src="http://avss.b15.cnwg.cn/cou ...
QQ聊天灌水机简要分析
QQ聊天灌水机简要分析 Writter: SkyJacker Date:2007-02-05 Http://blog.csdn.net/skyjacker 1.获取聊天窗口 FindWindow ...
隐士打造CSDN相册灌水机 (1)
CSDN的相册发照片实在是简陋,一个iframe,还在iframe里面露点了,露点照参见http://blog.csdn.net/nethermit/archive/2007/01/12/148152 ...
VBS论坛自动灌水机代码
请根据你的浏览器,选择相应的程序 IE浏览器: set wind9=createobject("scripting.filesystemobject") if wind9.file ...

BBS灌水机脚本(vb scritp, telnet, bbs, sterm)

BBS灌水机脚本(vb scritp, telnet, bbs, sterm)相关推荐

最新文章

热门文章