说明：

计算一个数字的绝对值。数字的绝对值是不含正、负号的数字。

使用：

ABS(数字)，用带有您希望删除的符号的合并字段、表达式或其他数值替换数字。

示例：

ABS(ExpectedRevenue) 计算预期收入金额的正值，而无论其为正还是为负。

说明：

返回的日期是，指定日期之前或之后的指定月数。如果指定日期是当月的最后一天，则结果日期是当月的最后一天。否则，结果包含与指定日期相同的日期组件。

使用：

ADDMONTHS (date，num) 并使用起始日期 num 和添加的月数替换 date。

示例：

ADDMONTHS (StartDate, 5)

为开始日期添加 5 个月。例如，如果开始日期是 2017 年 9 月 20 日，结果日期是 2018 年 2 月 20 日；如果开始日期是 2017 年 9 月 30 日，结果日期是 2018 年 2 月 28 日。

说明：

确定文本是否以特定字符开头，如果是则返回 TRUE（真）。如果不是，则返回 FALSE。

使用：

BEGINS(文本, 比较文本)，用您希望进行比较的字符或字段替换文本, 比较文本。

示例：

IF(BEGINS (Product_type__c , “ICU”), “Medical”, “Technical”)

如果产品类型自定义文本字段中的文本以“ICU”开头，则此示例返回文本“Medical”。对于所有其他产品显示 Technical。

技巧提示：

此函数区分大小写，因此，请确保compare_text值的大小写正确无误。

在验证规则或工作流规则中使用此函数时，留空的字段被视为有效。例如，如果您的验证规则要测试资产序列号是否以“3”开始，则序列号为空的所有资产都将视为有效。

说明：

确定表达式是否有值，如果没有值，则返回替代表达式。如果表达式有值，则返回表达式的值。

使用：

BLANKVALUE(表达式, 置换表达式)，用您希望计算的表达式替换表达式，用您希望替换任何空白值的值替换置换表达式。

示例：

示例 1

BLANKVALUE(Department, “Undesignated”)

如果部门字段包含值则此公式返回部门字段的值。如果部门字段为空，则此公式返回词语未指定。

示例 2

(BLANKVALUE(Payment_Due_Date__c, StartDate +5)

此公式返回当付款到期日期为空时，合同开始日期之后第五天的日期。付款到期日期是自定义日期字段。

技巧提示：

在新公式中使用 BLANKVALUE 替代 NULLVALUE。BLANKVALUE 与 NULLVALUE 功能相同，但还支持文本字段。Salesforce 继续支持 NULLVALUE，您不需要更改现有公式。

如果字段包含字符、空白或零，则则字段不为空。例如，如果字段包含使用空格键插入的空格，则该字段不为空。

如果字段没有值，则使用 BLANKVALUE 函数返回指定字符串；如果您只想检查字段是否有值，则使用 ISBLANK 函数。

如果您对数值字段使用该函数，则字段没有值且未配置将空白字段处理为零时，该函数只返回指定字符串。

说明：

在文本字符串中插入一个换行符。

使用：

BR()

示例：

CASE(ShippingCountry,

"USA",

ShippingStreet & BR() &

ShippingCity & ",

" & ShippingState & " " &

ShippingPostalCode & BR()

& ShippingCountry,

"France",

ShippingStreet & BR() &

ShippingPostalCode & " " &

ShippingCity & BR() &

ShippingCountry, "etc")

此公式字段以标准格式显示联系人的带格式邮寄地址，根据所在的国家/地区，可能会在该地址的适当位置中包含空格和换行符。

技巧提示：

请勿删除函数名称后面的括号。

保留括号为空。括号中不包含值。

请勿忘记在 BR() 两侧加上串联运算符：&。

请勿在邮件合并模板中使用此函数。

此函数在自定义按钮和链接、S-Control 或报表中不可用。

说明：

根据一系列值检查一个给定表达式。如果表达式等于其中一个值，则返回相应结果。如果它不等于任何值，则返回else_result。

使用：

CASE(expression,value1, result1, value2, result2,..., else_result)，用要与所指定的每个值进行比较的字段或值替换 expression。必须用相等的值替换每个值和结果以返回结果项。当表达式不等于任何值时，用您希望返回的值替换else_result。

公式字段示例：

个案未处理的天数

这是一个自定义公式字段未处理天数的示例，使用该示例可根据个案未处理的天数显示不同的文本：

CASE(Days_Open__c, 3,

"Reassign", 2, "Assign Task", "Maintain")

显示下面的文本：

为任何三天未处理的个案显示“Reassign”（重新指定）。

为任何有两天未处理的个案显示“Assign Task”（分配任务）。

为所有其他个案显示“Maintain”（维护）。

上次活动的月份

此公式字段显示上次活动的月份，如果没有活动，则显示无。

CASE(MONTH(LastActivityDate),

1, "January",

2, "February",

3, "March",

4, "April",

5, "May",

6, "June",

7, "July",

8, "August",

9, "September",

10, "October",

11, "November",

12, "December",

"None")

默认值示例：

折扣率

使用下面的默认值公式，可以根据业务机会创建人所在的部门在业务机会中插入另一个折扣率：

CASE(User.Department, "IT", 0.25, "Field", 0.15, 0)

在本示例中，该公式在“IT”部门的用户创建的所有业务机会上插入了 25% 的折扣率，或在“现场”部门的人员创建的所有业务机会上插入了 15% 的折扣率。如果创建者不属于其中任何一个部门，则折扣率为零。这是业务机会中使用标准用户字段部门的自定义百分比字段。

产品语言

您可能希望将产品与其语言关联起来，以便用户了解要包含的文档或适配器的类型。使用下面的默认值公式可根据创建某产品的用户所属的国家自动设置该产品的语言。在本例中，如果用户的国家是日本，则默认值是日语；如果用户的国家是美国，默认值是英语。如果两者都不是，则会将默认值未知插入到产品语言字段。

CASE($User.Country ,"Japan", "Japanese", "US", "English","unknown")

技巧提示：

请确保您的值1 和值2 等表达式属于相同的数据类型。

请确保您的结果1 和结果2 等表达式属于相同的数据类型。

CASE 函数中不能包含返回真或假的函数，而应当确保真或假表达式返回数字，例如：

CASE(1, IF(ISPICKVAL​ (Term__c, "12"),​ 1, 0),

12 * Monthly_Commit__c,​​

IF(ISPICKVAL(Term__c, "24"), 1, 0),​​

24 * Monthly_Commit__c, 0)

在该公式中，期限是一个选项列表字段，当它包含表示真的值 1 时，将与“每月提交量”相乘。

需包含其他结果值。

如果任何表达式返回一个错误，那么，即使其他表达式返回的值正确，CASE 函数也将返回一个错误。例如，在 CASE(Field__c,"Partner", "P",​ "Customer", "C", LEFT(Field__c, -5)) 公式中，即使其中字段的值是“Partner”（合作伙伴）或“Customer”（客户），该公式也会由于上一条语句不合逻辑而返回一个错误。

如果 CASE 函数中的字段为空，它将返回其他结果值。例如，如果 未处理天数字段为空、0 或者 2 和 3 以外的任何值，CASE(Days_Open__c, 3, "Reassign", 2,​ "Assign Task", "Maintain") 公式将显示Maintain。

使用 CASE 函数可以确定选项列表值是否等于特定的值。例如，当期限为 12 时，CASE(Term__c, "12", 12 * Monthly_Commit__c, "24",​ 24 * Monthly_Commit__c, 0) 公式将每月提交量乘以 12；当期限为 24 时，该公式将每月提交量乘以 24。否则，结果为零。

说明：

将 15 个字符的 ID 转换成区分大小写的 18 个字符 ID。

使用：

CASESAFEID(id) 并用对象 ID 替代 id。

示例：

CASESAFEID (Id)

此公式将 15 个字符的 ID 替换为 18 个字符、区分大小写的 ID。

技巧提示：

转换为 18 个字符的 ID 可更好地与 Excel 兼容。

CASESAFEID 函数可用于定义报表和 S-Control 以外的公式。

说明：

将数字向上四舍五入为最接近的整数；如果是负数，避免四舍五入为零。

使用：

CEILING(数字)，用您希望舍入的字段或表达式替换数字。

示例：

CEILING(2.5) 返回 3，即 2.5 向上舍入为最接近的整数。

CEILING(-2.5) 会返回 -3，即 -2.5 舍入为 0 以下的负数。

说明：

比较两个文本参数，如果第一个参数包含第二个参数，则返回 TRUE（真）。如果不包含，则返回 FALSE（假）。

使用：

CONTAINS(文本, 比较文本) 并使用包含比较文本的值的文本替换文本。

示例：

IF(CONTAINS(Product_Type__c, "part"), "Parts", "Service")

此公式检查自定义文本字段 Product_Type 的内容，并针对任何包含单词“part的产品返回 Parts。否则，将返回 Service。请注意，如果 Product_Type 字段包含“Part”或“PART”文本，此公式将返回 Services。

技巧提示：

此函数区分大小写，因此，请确保compare_text值的大小写正确无误。

在验证规则或工作流规则中使用此函数时，留空的字段被视为有效。例如，如果您的验证规则用来测试资产序列号是否包含“A”，那么，所有具有空序列号的资产将被视为有效。

CONTAINS 函数不支持多选选项列表。使用 INCLUDES 以查看多选选项列表是否有特定值。

说明：

对于指定币种 ISO 代码，返回企业币种的汇率。如果币种无效，返回 1.0。

使用：

CURRENCYRATE(currency_ISO_code)，并使用币种 ISO 代码（例如“USD”）替换 currency_ISO_code。

示例：

CURRENCYRATE(”USD”) 返回与美元的汇率。