oracle raise_application_error mysql_Oracle PL/SQL中异常高级特性
在OraclePL/SQL语句块中exception的异常处理部分是非常重要的组成部分,它决定了在PL/SQL语句块内部可执行部分在发生异常错误时,程序是友好地提示:程序遇到某些错误而无法执行,还是抛出一堆难以理解的Oracle内部错误码。
本文只介绍3中PL/SQL异常的三种高级形态,用于解决Oracle内置异常过少,很多时候不能够满足实际的使用需求。
1,RAISE_APPLICATION_ERROR
- 是Oracle提供的一种特殊的内置过程,允许程序员为特定的程序创建有意义的错误消息,适用于用户自定义定义异常。
- 语法结构
RAISE_APPLICATION_ERROR (error_number,error_message);或者
RAISE_APPLICATION_ERROR (error_number,error_message,keep_errors)
- error_number 是与特定错误消息关联的错误编号,Oracle预留了-20999 -- -20000专门提供给程序员自定义错误代码。
- error_message 是错误消息文本,最多包含2048个字符。
- keep_errors 是可选的Boolean参数,默认为FALSE,如果为TRUE,新抛出的错误会被添加到已抛出的错误列表中,这个错误列表称为错误栈,如果为FALSE,新错误会替换已抛出的错误栈。
- 适用于未命名的用户定义异常,负责把错误编号和错误消息关联,用户定义了异常,却没有定义该错误的名称
- 使用RAISE_APPLICATION_ERROR过程,程序员能够遵循与Oracle一致的方式返回错误消息。
- 示例代码
declare
v_id number := &p_id;
v_name varchar2(20);
v_sal number;
begin
if v_id > 0 then
select ename,sal into v_name,v_sal from emp where empno = v_id;
dbms_output.put_line(chr(10)||v_name||' '||v_sal);
else
raise_application_error (-20001,'Employee id can not be negative.');
end if;
exception
when NO_DATA_FOUND then
dbms_output.put_line(chr(10)||'There is no such employee id is '||v_id);
end;
/
Enter value for p_id: 40
old 2: v_id number := &p_id;
new 2: v_id number := 40;
There is no such employee id is 40
PL/SQL procedure successfully completed.
/
Enter value for p_id: -90
old 2: v_id number := &p_id;
new 2: v_id number := -90;
declare
*
ERROR at line 1:
ORA-20001: Employee id can not be negative.
ORA-06512: at line 11
- 示例解析:该PL/SQL代码会根据用户输入的员工Id,查询员工的姓名和工资。当我们输入存在的员工编号时,程序能够正常返回结果;如果输入不存在ID,则select into语句会抛出没有返回行,进而使程序进入异常处理部分(本部分为举例),程序同样执行成功;当输入一个负数时,if条件语句就会进入到raise_application_error部分,由于可执行部分运行发生错误,执行焦点会立即转移到异常处理部分,而异常处理部分没有关于该异常的处理,所以程序报错,并返回到用户界面。
- 是哟个raise_application_error,程序员可以使程序实现像Oracle系统产生的错误消息。
- 事实上,单纯使用raise_application_error,因为没有异常的名称,如果要对其进行异常处理,只能够使用others(下文有专门的介绍)。
2,EXCEPTION_INIT
- 使用EXCEPTION_INIT编译指令,可以将用户自定义的Oracle错误编号和用户自定义的错误名称关联起来,相当于用户自定义错误和RAISE_APPLICATION_ERROR的结合体。
- EXCEPTION_INIT 出现在语句块的声明部分:
exception_name exception;
pragma exception_init(exception_name,error_code)
- 考虑如下代码:
declare
v_no number := &p_no;
begin
delete from dept where deptno = v_no;
dbms_output.put_line(chr(10)||'The department id is '||v_no||' has been deleted');
end;
/
Enter value for p_no: 20
old 2: v_no number := &p_no;
new 2: v_no number := 20;
declare
*
ERROR at line 1:
ORA-02292: integrity constraint (SCOTT.FK_DEPTNO) violated - child record found
ORA-06512: at line 4
- 由于违反外键约束,删除部门失败了。但是抛出的错误不是很好理解
- 我们可以使用EXCEPTION_INIT来对这个错误进行处理,首先我们得知道违反外键约束的这个Oracle错误代码“ORA-02292”
- 使用EXCEPTION_INIT
declare
v_no number := &p_no;
e_dept_exist exception;
pragma exception_init(e_dept_exist,-02292);
begin
delete from dept where deptno = v_no;
dbms_output.put_line(chr(10)||'The department id is '||v_no||' has been deleted');
exception
when e_dept_exist then
dbms_output.put_line(chr(10)||'There are some employees in this deptartment, if you want delete this deptartment ,please delete these employees in the department first.');
end;
/
Enter value for p_no: 20
old 2: v_no number := &p_no;
new 2: v_no number := 20;
There are some employees in this deptartment, if you want delete this deptartment ,please delete these employees in the department first.
PL/SQL procedure successfully completed.
- 这下抛出的错误就容易理解多了。首先我们定义了一个名为e_dept_exist的异常,然后将这个异常与Oracle错误代码 -02292 进行关联。当程序执行报错时进入异常处理部分,在这里我们重新给这个错误定义了错误消息。
3,SQLCODE 和 SQLERRM
- 在异常处理中,当异常的名称未知时(比如上面1中RAISE_APPLICATION_ERROR),都可以使用others来进行异常的捕获处理;
- 由于others所捕获的异常是未知的(也可以是已知的,但是在程序中没有将其枚举出来),因此需要使用Oracle提供的两个内置函数SQLCODE、SQLERRM来针对others的异常进行处理:
- SQLCODE 会返回Oracle的错误编号
- SQLERRM,返回错误的消息
- 示例1,处理Oracle系统返回的错误:
declare
v_no number := &p_no;
error_code number;
error_msg varchar2(500);
begin
delete from dept where deptno = v_no;
dbms_output.put_line(chr(10)||'The department id is '||v_no||' has been deleted');
exception
when others then
error_code := sqlcode;
error_msg := sqlerrm;
dbms_output.put_line(chr(10)||'Error code is: '||error_code);
dbms_output.put_line(chr(10)||'Error message is: '||error_msg);
end;
Enter value for p_no: 10
old 2: v_no number := &p_no;
new 2: v_no number := 10;
Error code is: -2292
Error message is: ORA-02292: integrity constraint (SCOTT.FK_DEPTNO) violated - child record found
PL/SQL procedure successfully completed.
- 请注意exception异常处理部分,在该部分里面我们用到了声明部分定义的两个变量,error_code用来存储SQLCODE,error_msg用来存储SQLERRM。然后将两个变量值打印出来。
- 示例2,处理用户自定义的异常:
declare
v_id number := &p_id;
v_name varchar2(20);
v_sal number;
begin
if v_id > 0 then
select ename,sal into v_name,v_sal from emp where empno = v_id;
dbms_output.put_line(chr(10)||v_name||' '||v_sal);
else
raise_application_error (-20001,'Employee id can not be negative.');
end if;
exception
when NO_DATA_FOUND then
dbms_output.put_line(chr(10)||'There is no such employee id is '||v_id);
when others then
declare
error_code number;
error_msg varchar2(500);
begin
error_code := sqlcode;
error_msg := sqlerrm;
dbms_output.put_line(chr(10)||'Error code is: '||error_code);
dbms_output.put_line(chr(10)||'Error message is: '||error_msg);
end;
end;
/
Enter value for p_id: -90
old 2: v_id number := &p_id;
new 2: v_id number := -90;
Error code is: -20001
Error message is: ORA-20001: Employee id can not be negative.
PL/SQL procedure successfully completed.
- 在本代码中使用了raise_application_error,由于单纯的使用raise_application_error,只能使用others进行捕获。在异常处理部分,我们使用了一个PL/SQL语句块来处理这个错误,声明两个变量,并将SQLCODE和SQLERRM以字面值赋值的方法给这两个变量。
oracle raise_application_error mysql_Oracle PL/SQL中异常高级特性相关推荐
- Oracle PL/SQL中异常高级特性
在OraclePL/SQL语句块中exception的异常处理部分是非常重要的组成部分,它决定了在PL/SQL语句块内部可执行部分在发生异常错误时,程序是友好地提示:程序遇到某些错误而无法执行,还是抛 ...
- oracle returning into,PL/SQL 中Returning Into的用法
ORACLE的DML语句中可以指定RETURNING INTO语句.RETURNING INTO语句的使用在很多情况下可以简化PL/SQL编程,少一次select into语句. DELETE操作:R ...
- pl/sql 中关于exception的学习笔记
1.异常的优点 如果没有异常,在程序中,应当检查每个命令的成功还是失败,如 BEGIN SELECT ... -- check for 'no data found' error SELECT ... ...
- 金仓数据库KingbaseES 迁移工具—PL/SQL中Oracle和KingbaseES 的对比
关键字: KingbaseES.PL/SQL.存储过程.函数 一.PL/SQL语言兼容特性 在 PL/SQL 语言方面,KingbaseES 提供了大量的Oracle 兼容特性.这些特性使得大多数的 ...
- Oracle在Pl/sql中的存储过程----zhoudianzhang
Oracle 存储过程 目录 Oracle 存储过程... 1 Oracle存储过程基础知识... 1 Oracle存储过程的基本语法... 2 关于Oracle存储过程的若干问题备忘... 4 1. ...
- PL/SQL中查询Oracle大数(17位以上)时显示科学计数法的解决方法
PL/SQL中查询Oracle大数(17位以上)时显示科学计数法的解决方法 参考文章: (1)PL/SQL中查询Oracle大数(17位以上)时显示科学计数法的解决方法 (2)https://www. ...
- oracle sql字符拆分字符串函数,oracle-是否有在PL / SQL中拆分字符串的功能?
oracle-是否有在PL / SQL中拆分字符串的功能? 我需要编写一个过程来规范具有由一个字符连接的多个令牌的记录. 我需要获得这些令牌来分割字符串,并将每个令牌作为新记录插入表中. Oracle ...
- oracle 偶数与奇数,在PL / SQL中计算数字中的奇数和偶数
我们给定一个正整数数字,任务是使用PL / SQL计算数字中奇数和偶数的计数. PL / SQL是SQL与编程语言的过程功能的组合.它是由Oracle Corporation在90年代初开发的,目的是 ...
- 在pl/sql中使用exp/imp工具实现oracle数据导出/导入
在pl/sql中使用exp/imp工具实现oracle数据导出/导入 2006年11月19日 星期日 10:59 Oracle 数据导入导出imp/exp就相当于oracle数据还原与备份.exp命令 ...
最新文章
- 【图论专题】差分约束系统
- UNIX下C语言的图形编程-curses.h函数库
- 求高精度幂(java)
- html5语义元素表,HTML5的结构和语义(3):语义性的块级元素
- js 面向对象例子
- 矩池云上安装caffe gpu教程
- 集群服务器分析系统,集群服务器系统可扩展性的研究与实现
- Gatech OMSCS的申请和学习之奥妙
- Rational Rose如何删除线段
- 那么如何成为优秀的机械工程师,如何提升自己的实力,有哪些值得注意和学习的呢?
- 电力系统微型计算机继电保护2018,2018年4月高等教育自学考试电力系统微型计算机继电保护试题及答案.docx...
- 东西湖职业技术学校计算机,武汉东西湖职业技术学校中专
- [AISTATS21]Towards Flexible Device Participation in Federated Learning阅读笔记
- 批发记账本软件隐私政策
- 阿里云的短信服务acsClient+java
- 一本值得反复学习的好书——《重构》读后感
- TPLinker实体关系抽取新范式TPLinker:单阶段联合抽取,并解决暴漏偏差~
- 基础操作案例:ArcGIS PRO基础教程(二)
- simplexmlelement object php,php – 访问SimpleXMLElement对象的某些属性
- 软件工程师如何估算项目时间
热门文章
- 在启动Tomcat 6.0时发现第一条信息便是: The Apache Tomcat Native library which allows optimal performance in produc
- Tina理财笔记(二)——万能险的收益和退保选择
- Python try except 异常类型及raise的使用
- 谈一谈|小白如何体验人工智能项目
- C语言 编辑题:平均数计算器
- 互链跨年调研:近9成专业人士认为今年会出现区块链标志性应用
- java--手动输入人数随机抽查班级同学名字的班级点名器
- 微信网页开发,动态修改页面Title
- 旅游网站推广经验的个人心得和看法!
- 怎么证明一个一维函数连续