*VWRITE这个命令只能通过file-->read input from...实现, 不能在窗口输入执行，否则会出现如下警告：

邢静忠编写的[ANSYS7.0 分析与工程应用]一书中大多例子都提到*VWRITE这个命令，第4页便有，可我怎么一用就出现问题？我见网上也有这样的例子，在ANSYS帮助里面例子也有用*VWRITE命令的，出现问题如下：
*** WARNING *** CP= 10.936 TIME= 08:26:10
In the graphical user interface,the *VWRITE command can only be
executed from an external file such as /INPUT or *USE. The command is
ignored.

*** WARNING *** CP= 10.976 TIME= 08:26:11
Error in format, not enough data format specifiers
.
*** WARNING *** CP= 11.016 TIME= 08:26:11
(1X,A8,' is not a recognized POST1 command, abbreviation, or macro.
This command will be ignored.

*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)(1X,A8,' ',F10.3,' ',1F5.3)
/COM,---------------------------------------------------
/OUT
FINISH  
*LIST,EX1_1,OUT

原程序为：
FINISH
/CLEAR,NOSTART
/FILENAME,EX1.1
/CWD,g:\ansysxuexi\EX1_1
/title,deflection of a hinged support
*AFUN,DEG
THETA=30
A=10000
B=A/2*TAN(THETA)
/PREP7
N,1
N,2,A/2,-B
N,3,A
ET,1,LINK1
R,1,1000
MP,EX,1,210E3
E,1,2
E,2,3
D,1,ALL,,,3,2
F,2,FY,-1000
OUTPR,,1
FINISH
/SOLU
SOLVE
FINISH
/POST1
PLDISP,2
MID_NODE=NODE(A/2,-B,0)
*GET,DISP,NODE,MID_NODE,U,Y
LEFT_EL=ENEARN(MID_NODE)
ETABLE,STRS,LS,1
*GET,STRSS,ELEM,LEFT_EL,ETAB,STRS

*DIM,LABEL,CHAR,2
*DIM,VALUE,,2,3
LABEL(1)='STRS_MPa','DEF_mm'
*VFILL,VALUE(1,1),DATA,1,-0.05498
*VFILL,VALUE(1,2),DATA,STRSS,DISP
*VFILL,VALUE(1,3),DATA,ABS(STRSS/1),ABS(DISP/0.05498)
/OUT,EX1_1,out
/COM
/COM,-----------EX1.1 RESULTS COMPARISON-----------
/COM,
/COM, |TARGET|ANSYS|RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,---------------------------
/OUT
FINISH
*LIST,EX1_1,out

到红色这条语句就提示错了，上面这段是从《ANSYS 7.0 分析实例与工程应用》2004版 第二章 2.2节“工字形截面外伸梁的平面弯曲”里面抄录的，如果有差别的话就差在空格数和“-”的数量了。
(1X,A8,' ',F10.3,' ',1F5.3) 另外，这句是什么意思？

解答：

(1X,A8,' ',F10.3,' ',1F5.3) 的作用是控制输出到EX2_2.OUT 文件中的数据格式，这句应该在*VWRITE后另起一行，简单运行了一下，可以把红色部分替换成下面格式

*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)

(1X,A8,3X,F10.3,5X,F8.3,5X,F8.3)

其中1X表示一个空格数，A8是输出字符型LABEL，占8位（列），F10.3表示浮点型数值，占据10列，小数3位，F8.3表示浮点型数值，占据8列，小数3位

谢谢斑竹！
我试了下确实可以输出了，甚至去掉所有1x之类的空格，保留逗号，结果都可以输出，只不过结果表格稍有变化，是不是说原来出错的原因在于没有换行？
（1X,A8,3X,F10.3,5X,F8.3,5X,1F8.3)，看到过这么个语句，红色的那个“1”代表啥意思？

解答：

这是一个数字，看下面的例子，A8对应LABEL(1)，F10.3对应VALUE(1,1)，2F8.3对应VALUE(1,2)和VALUE(1,3)，应该清楚了吧

*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,3X,F10.3,2F8.3)