这里只介绍动态SQL的使用。关于动态SQL语句的语法，参见：http://blog.csdn.net/chiclewu/article/details/16097133

1.什么是时候需要使用动态SQL？

SQL文本在编译时是未知的。

例如，SELECT语句包含的标识符(如表名)在编译时是未知的，或者WHERE子句的条件数量在编译时是未知。

静态SQL不支持

例如，在PL/SQL中用静态SQL只能执行查询以及DML语句。如果想要执行DDL语句，只能使用动态SQL。

当让使用静态SQL，也有它的好处：

编译成功验证了静态SQL语句引用有效的数据库对象和访问这些对象的权限
编译成功创建了模式对象的依赖关系

2.EXECUTE IMMEDIATE语句

EXECUTE IMMEDIATE语句的意思是使用本地动态SQL处理大多数动态SQL语句。

如果动态SQL语句是自包含的（也就是说，它的绑定参数没有占位符，并且结果不可能返回错误），则EXECUTE IMMEDIATE语句不需要子句。

如果动态SQL语句包行占位符绑定参数，每个占位符在EXECUTE IMMEDIATE语句的子句中必须有一个相应的绑定参数，具体如下：

如果动态SQL语句是一个最多只能返回一行的SELECT语句，OUT绑定参数放置在INTO子句，IN绑定参数放置在USING子句。
如果动态SQL语句是一个可以返回多行的SELECT语句，OUT绑定参数放置在BULK COLLECT INTO子句，IN绑定参数放置在USING子句。
如果动态SQL语句是一个除了SELECT以外的其他DML语句，且没有RETURNING INTO子句，所有的绑定参数放置在USING子句中。
如果动态SQL还语句一个匿名PL/SQL块或CALL语句，把所有的绑定参数放置在USING子句中。

如果动态SQL语句调用一个子程序，请确保：

每个对应子程序参数占位符的绑定参数与子程序参数具有相同的参数模式和兼容的数据类型。
绑定参数不要有SQL不支持的数据类型（例如，布尔类型,关联数组，以及用户自定的记录类型）

USING子句不能包含NULL字面量。如果想要在USING子句中使用NULL值，可以使用位初始化的变量或者函数显示将NULL转换成一个有类型的值。

2.1动态SQL语句是一个最多只能返回一行的SELECT语句

使用动态SQL语句返回单列，查询SCOTT的薪水：

declare
v_sql_text varchar2(1000);
v_sal number;
v_ename emp.ename%type := 'SCOTT';
begin
v_sql_text := 'select e.sal from emp e where e.ename = :ename';

execute immediate v_sql_text
into v_sal
using v_ename;

dbms_output.put_line(v_ename || ':' || v_sal);

end;

使用动态SQL返回一条记录，查询SCOTT的基本信息：

declare
v_sql_text varchar2(1000);
v_ename    emp.ename%type := 'SCOTT';
vrt_emp    emp%rowtype;
begin
v_sql_text := 'select * from emp e where e.ename = :ename';
execute immediate v_sql_text
    into vrt_emp
    using v_ename;
dbms_output.put_line(v_ename || '的基本信息:');
dbms_output.put_line('工号:' || vrt_emp.empno);
dbms_output.put_line('工资:' || vrt_emp.sal);
dbms_output.put_line('入职日期:' || vrt_emp.hiredate);

end;

2.2动态SQL语句是一个可以返回多行的SELECT语句

2.2.1只有一个占位符

使用动态SQL语句返回多行记录，查询30部门的员工基本信息：

declare
v_sql_text varchar2(1000);
v_deptno emp.deptno%type := 30;

type nt_emp is table of emp%rowtype;
vnt_emp nt_emp;
begin
v_sql_text := 'select * from emp e where e.deptno = :deptno';
execute immediate v_sql_text bulk collect
into vnt_emp
using v_deptno;

for i in 1 .. vnt_emp.count loop
    dbms_output.put_line(vnt_emp(i).ename || '的基本信息:');
    dbms_output.put_line('工号:' || vnt_emp(i).empno);
    dbms_output.put_line('工资:' || vnt_emp(i).sal);
    dbms_output.put_line('入职日期:' || vnt_emp(i).hiredate);
    dbms_output.put_line('');
end loop;

end

2.2.2多个占位符

查询20部门工资大于2000的员工基本信息：

declare
v_sql_text varchar2(1000);
v_deptno emp.deptno%type := 20;
v_sal number := 2000;

type nt_emp is table of emp%rowtype;
vnt_emp nt_emp;
begin
v_sql_text := 'select * from emp e where e.sal>:sal and e.deptno = :deptno';
execute immediate v_sql_text bulk collect
into vnt_emp
using v_sal, v_deptno; --注意绑定多个变量时，绑定变量只与占位符位置有关，与占位符名称无关，

注意：对于SQL文本，占位符名称是没有意义的，绑定变量与占位符名称无关，只与占位符的配置有关。即使有多个相同名称占位符，也需要每个占位符对应一个绑定变量。对于PL/SQL块，占位符名称是有意义的，相同名称的占位符，只需要第一个占位符绑定变量。

2.3动态SQL语句是一个带有RETURNING子句的DML语句

KING的工资增长20%，返回增长后的工资：

eclare
v_sql_text varchar2(1000);
v_sal number;
v_ename emp.ename%type := 'KING';
begin

v_sql_text := 'update emp e set e.sal= e.sal*1.2 where e.ename = :ename returning e.sal into :sal';

execute immediate v_sql_text
using v_ename
returning into v_sal;

dbms_output.put_line(v_ename || ':' || v_sal);

end;

注意：只有当v_sql_text语句有returning into子句时,动态SQL语句才能使用returning into子句。

2.4给占位符传递NULL值

2.4.1通过未初始化变量传递NULL值

declare
v_sql_text varchar2(1000);
v_deptno emp.ename%type := 'ALLEN';
v_comm emp.comm%type;

begin
v_sql_text := 'update emp e set e.comm = :comm where e.ename =:ename';
execute immediate v_sql_text
using v_comm, v_deptno;
end;

2.4.2通过函数将NULL值显式的转换成一个有类型的值

declare
v_sql_text varchar2(1000);
v_deptno emp.ename%type := 'ALLEN';
begin
v_sql_text := 'update emp e set e.comm = :comm where e.ename =:ename';
execute immediate v_sql_text
using to_number(null), v_deptno;
end;

3.OPEN FOR语句

PL/SQL引入OPEN FOR语句实际上并不是为了支持本地动态SQL，而是为了支持游标变量。现在它以一种极其优雅的方式实现了多行的动态查询。

使用OPEN FOR语句来关联动态SQL语句的游标变量，在OPEN FOR语句的USING子句中，指定动态SQL语句每个占位符的绑定参数。
使用FETCH语句获取运行时结果集。
使用CLOSE语句关闭游标变量

使用OPEN FOR语句查询出10部门的员工的基本信息：

declare
type rc_emp is ref cursor;
vrc_emp rc_emp;

v_sql_text varchar2(1000);
v_deptno emp.deptno%type := 10;
vrt_emp emp%rowtype;

begin
v_sql_text := 'select * from emp e where e.deptno=:deptno';

open vrc_emp for v_sql_text
    using v_deptno;
loop
    exit when vrc_emp%notfound;
    fetch vrc_emp
      into vrt_emp;

    dbms_output.put_line(vrt_emp.ename || '的基本信息:');
    dbms_output.put_line('工号:' || vrt_emp.empno);
    dbms_output.put_line('工资:' || vrt_emp.sal);
    dbms_output.put_line('入职日期:' || vrt_emp.hiredate);
    dbms_output.put_line('');

end loop;
close vrc_emp;

end;

4.重复的占位符名称

如果在动态SQL语句重复占位符名称，要知道占位符关联绑定参数的方式依赖于动态语句的类型。

如果执行的是一个动态SQL字符串，则必须为每一个占位符提供一个绑定参数，即使这些占位符是重复的。
如果执行的是一个动态PL/SQL块，则必须为每一个唯一占位符提供一个绑定参数，即重复的占位符只需要提供一个绑定参数。

4.1重复占位符的动态SQL字符串

declare
v_sql_text varchar2(1000);
v_sal      emp.sal%type := 4000;
v_comm     emp.comm%type;
v_ename    emp.ename%type := 'SCOTT';
begin

v_sql_text := 'update emp e set e.sal=:sal , e.comm = :sal*0.1 where e.ename =:ename returning e.comm into :comm ';

execute immediate v_sql_text
using v_sal, v_sal, in v_ename
returning into v_comm;
dbms_output.put_line(v_ename || '分红:' || v_comm);

end;

4.2重复占位符的动态PL/SQL块

declare
v_sql_text varchar2(1000);
v_sal number;
v_ename emp.ename%type := 'KING';
begin

v_sql_text := ' begin select e.sal,e.ename into :sal,:ename from emp e where e.ename =:ename; end;';

execute immediate v_sql_text
using out v_sal, in out v_ename;
dbms_output.put_line(v_ename || ':' || v_sal);

end;

如何使用动态SQL语句？相关推荐

Oracle基础动态SQL语句
一.静态SQL和动态SQL的概念. 1.静态SQL 静态SQL是我们常用的使用SQL语句的方式,就是编写PL/SQL时,SQL语句已经编写好了.因为静态SQL是在编写程序时就确定了,我们只能使用SQL ...
动态SQL语句--mybatis
转自:http://www.blogjava.net/Steven-bot/articles/363460.html 动态SQL语句--mybatis 动态SQL语句有些时候,sql ...
oracle中执行动态sql语句吗,oracle中有没有可动态执行sql语句的函数
oracle中有没有可动态执行sql语句的函数关注:233 答案:2 手机版解决时间 2021-03-05 15:53 提问者祗剩寂寞 2021-03-04 22:38 oracle中有没有可 ...
Mybatis Plus 是如何实现动态 SQL 语句的？原理你懂吗？
作者 | 稻草江南来源 | https://juejin.cn/post/6883081187103866894 Mybatis-Plus(简称MP)是一个 Mybatis 的增强工具,那么它是怎么 ...
Sql Server实用操作-动态sql语句基本语法
如何将exec执行结果放入变量中? declare @num int, @sqls nvarchar(4000) set @sqls='select @a=count(*) from tableNam ...
IBatis.net动态SQL语句
在学习动态SQL语句之前,首先必须对条件查询有一定了解,先来学习如何向IBatis.Net的映射文件里传入参数. 一.条件查询 1.传递单个参数如根据Id查询: <select id=&quo ...
Mybatis映射文件动态SQL语句-01
因为在很多业务逻辑复杂的项目中,往往不是简单的sql语句就能查询出来自己想要的数据,所有mybatis引入了动态sql语句, UserMapper.xml <?xml version=" ...
MyBatis——动态SQL语句——if标签和where标签复合使用
功能需求根据性别和名字查询用户官方文档 MyBatis--动态 SQL SQL语句 SELECT id, username, birthday, sex, address FROM `user` ...
oracle不使用游标,oracle – 为什么我们不能在动态SQL语句中使用强引用游标？
这是一个带有强类型引用游标的过程: SQL> create or replace procedure p1 is 2 type dept_rc is ref cursor return dept ...
oracle 带有变量的语句_Oracle 动态SQL语句（2）之含变量的WHERE语句与日期变量
在 Oracle 动态SQL语句(1)中提到基本动态SQL语句书写,但在写动态SQL语句时特别要注意日期型变量和WHERE语句的编写. 如下代码: 1.注意在执行动态SQL语句时,execute im ...

如何使用动态SQL语句？

1.什么是时候需要使用动态SQL？

2.EXECUTE IMMEDIATE语句

2.1动态SQL语句是一个最多只能返回一行的SELECT语句

2.2动态SQL语句是一个可以返回多行的SELECT语句

2.2.1只有一个占位符

2.2.2多个占位符

2.3动态SQL语句是一个带有RETURNING子句的DML语句

2.4给占位符传递NULL值

2.4.1通过未初始化变量传递NULL值

2.4.2通过函数将NULL值显式的转换成一个有类型的值

3.OPEN FOR语句

4.重复的占位符名称

4.1重复占位符的动态SQL字符串

4.2重复占位符的动态PL/SQL块

如何使用动态SQL语句？相关推荐

最新文章

热门文章